home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / LANG / ADA / GNAT / !gcc / adainc / 6 / ads / s-ficobl next >
Text File  |  1996-02-12  |  8KB  |  157 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUN-TIME COMPONENTS                         --
  4. --                                                                          --
  5. --              S Y S T E M . F I L E _ C O N T R O L _ B L O C K           --
  6. --                                                                          --
  7. --                                 S p e c                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.7 $                              --
  10. --                                                                          --
  11. --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22. -- MA 02111-1307, USA.                                                      --
  23. --                                                                          --
  24. -- As a special exception,  if other files  instantiate  generics from this --
  25. -- unit, or you link  this unit with other files  to produce an executable, --
  26. -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27. -- covered  by the  GNU  General  Public  License.  This exception does not --
  28. -- however invalidate  any other reasons why  the executable file  might be --
  29. -- covered by the  GNU Public License.                                      --
  30. --                                                                          --
  31. -- GNAT was originally developed  by the GNAT team at  New York University. --
  32. -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33. --                                                                          --
  34. ------------------------------------------------------------------------------
  35.  
  36. --  This package contains the declaration of the basic file control block
  37. --  shared between Text_IO, Sequential_IO, Direct_IO and Streams.Stream_IO.
  38. --  The actual control blocks are derived from this block by extension. The
  39. --  control block is itself derived from Ada.Streams.Root_Stream_Type which
  40. --  facilitates implementation of Stream_IO.Stream and Text_Streams.Stream.
  41.  
  42. with Ada.Streams;
  43.  
  44. package System.File_Control_Block is
  45.  
  46.    -----------------------------
  47.    --  Ada File Control Block --
  48.    -----------------------------
  49.  
  50.    --  The Ada file control block is an abstract extension of the root
  51.    --  stream type. This allows a file to be treated directly as a stream
  52.    --  for the purposes of Stream_IO, or stream operations on a text file.
  53.    --  The individual I/O packages extend this type with package specific
  54.    --  fields to create the concrete types to which the routines in this
  55.    --  package can be applied.
  56.  
  57.    --  The type File_Type in the individual packages is an access to the
  58.    --  extended file control block. The value is null if the file is not
  59.    --  open, and a pointer to the control block if the file is open.
  60.  
  61.    type Pstring is access all String;
  62.    --  Used to hold name and form strings
  63.  
  64.    type File_Mode is (In_File, Inout_File, Out_File, Append_File);
  65.    --  File mode (union of file modes permitted by individual packages,
  66.    --  the types File_Mode in the individual packages are declared to
  67.    --  allow easy conversion to and from this general type.
  68.  
  69.    type Shared_Status_Type is (Yes, No, None);
  70.    --  This type is used to define the sharing status of a file. The default
  71.    --  setting of None is used if no "shared=xxx" appears in the form string
  72.    --  when a file is created or opened. For a file with Shared_Status set to
  73.    --  None, Use_Error will be raised if any other file is opened or created
  74.    --  with the same full name. Yes/No are set in response to the presence
  75.    --  of "shared=yes" or "shared=no" in the form string. In either case it
  76.    --  is permissible to have multiple files opened with the same full name.
  77.    --  All files opened simultaneously with "shared=yes" will share the same
  78.    --  stream with the semantics specified in the RM for file sharing. All
  79.    --  files opened with "shared=no" will have their own stream.
  80.  
  81.    type AFCB;
  82.    type AFCB_Ptr is access all AFCB'Class;
  83.  
  84.    type AFCB is abstract new Ada.Streams.Root_Stream_Type with record
  85.  
  86.       Stream : Address;
  87.       --  The file descriptor
  88.  
  89.       Name : Pstring;
  90.       --  A pointer to the file name. The file name is null for temporary
  91.       --  files, and also for standard files (stdin, stdout, stderr). The
  92.       --  name is always null-terminated if it is non-null.
  93.  
  94.       Form : Pstring;
  95.       --  A pointer to the form string. This is the string used in the
  96.       --  fopen call, and must be supplied by the caller (there are no
  97.       --  defaults at this level). The string is always null-terminated.
  98.  
  99.       Mode : File_Mode;
  100.       --  The file mode. No checks are made that the mode is consistent
  101.       --  with the form used to fopen the file.
  102.  
  103.       Is_Regular_File : Boolean;
  104.       --  A flag indicating if the file is a regular file
  105.  
  106.       Is_Temporary_File : Boolean;
  107.       --  A flag set only for temporary files (i.e. files created using the
  108.       --  Create function with a null name parameter, using tmpfile).
  109.  
  110.       Is_System_File : Boolean;
  111.       --  A flag set only for system files (stdin, stdout, stderr)
  112.  
  113.       Is_Text_File : Boolean;
  114.       --  A flag set if the file was opened in text mode
  115.  
  116.       Shared_Status : Shared_Status_Type;
  117.       --  Indicates sharing status of file, see description of type above
  118.  
  119.       Access_Method : Character;
  120.       --  Set to 'Q', 'S', 'T, 'D' for Sequential_IO, Stream_IO, Text_IO
  121.       --  Direct_IO file (used to validate file sharing request).
  122.  
  123.       Next : AFCB_Ptr;
  124.       Prev : AFCB_Ptr;
  125.       --  All open files are kept on a doubly linked chain, with these
  126.       --  pointers used to maintain the next and previous pointers.
  127.  
  128.    end record;
  129.  
  130.    ----------------------------------
  131.    -- Primitive Operations of AFCB --
  132.    ----------------------------------
  133.  
  134.    --  Note that we inherit the abstract operations Read and Write from
  135.    --  the base type. These must be overridden by the individual file
  136.    --  access methods to provide Stream Read/Write access.
  137.  
  138.    function AFCB_Allocate (Control_Block : AFCB) return AFCB_Ptr is abstract;
  139.    --  Given a control block, allocate space for a control block of the same
  140.    --  type on the heap, and return the pointer to this allocated block. Note
  141.    --  that the argument Control_Block is not used other than as the argument
  142.    --  that controls which version of AFCB_Allocate is called.
  143.  
  144.    procedure AFCB_Close (File : access AFCB) is abstract;
  145.    --  Performs any specialized close actions on a file before the file is
  146.    --  actually closed at the system level. This is called by Close, and
  147.    --  the reason we need the primitive operation is for the automatic
  148.    --  close operations done as part of finalization.
  149.  
  150.    procedure AFCB_Free (File : access AFCB) is abstract;
  151.    --  Frees the AFCB referenced by the given parameter. It is not necessary
  152.    --  to free the strings referenced by the Form and Name fields, but if the
  153.    --  extension has any other heap objects, they must be freed as well. This
  154.    --  procedure must be overridden by each individual file package.
  155.  
  156. end System.File_Control_Block;
  157.